d/freebsd-dev
1
0
Fork 0
Code Issues Pull Requests Packages Projects Releases Wiki Activity

Add support for sending messages to the serial console which is helpful

Browse Source 
when debugging boot problems.  It is not on by default but is enabled via
the BTX_SERIAL variable.  The port and speed can be set via the same
variables used by boot2 and the loader.
This commit is contained in:
John Baldwin 2001-11-03 22:09:30 +00:00
parent 0535c2bbad
commit 580d63df68
Notes: svn2git 2020-12-20 02:59:44 +00:00 
svn path=/head/; revision=85994
3 changed files with 163 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

9
sys/boot/i386/btx/btx/Makefile
View File

@ -14,6 +14,15 @@ BOOT_BTX_FLAGS=0x0
AFLAGS+= --defsym BTX_FLAGS=${BOOT_BTX_FLAGS}
.if defined(BTX_SERIAL)
BOOT_COMCONSOLE_PORT?= 0x3f8
BOOT_COMCONSOLE_SPEED?= 9600
B2SIOFMT?= 0x3
M4FLAGS+= -DBTX_SERIAL -DSIOPRT=${BOOT_COMCONSOLE_PORT} \
-DSIOFMT=${B2SIOFMT} -DSIOSPD=${BOOT_COMCONSOLE_SPEED}
.endif
ORG= 0x9000
all: btx

77
sys/boot/i386/btx/btx/btx.S
View File

@ -240,6 +240,9 @@ init.8: xorl %ecx,%ecx # Zero
movb $0x7,%cl # Set remaining
init.9: push $0x0 # general
loop init.9 # registers
ifdef(`BTX_SERIAL',`
call sio_init # setup the serial console
')
popa # and initialize
popl %es # Initialize
popl %ds # user
@ -967,6 +970,80 @@ putstr: lodsb # Load char
testb %al,%al # End of string?
jnz putstr.0 # No
ret # To caller
ifdef(`BTX_SERIAL',`
.set SIO_PRT,SIOPRT # Base port
.set SIO_FMT,SIOFMT # 8N1
.set SIO_DIV,(115200/SIOSPD) # 115200 / SPD
# void sio_init(void)
sio_init: movw $SIO_PRT+0x3,%dx # Data format reg
movb $SIO_FMT|0x80,%al # Set format
outb %al,(%dx) # and DLAB
pushl %edx # Save
subb $0x3,%dl # Divisor latch reg
movw $SIO_DIV,%ax # Set
outw %ax,(%dx) # BPS
popl %edx # Restore
movb $SIO_FMT,%al # Clear
outb %al,(%dx) # DLAB
incl %edx # Modem control reg
movb $0x3,%al # Set RTS,
outb %al,(%dx) # DTR
incl %edx # Line status reg
# void sio_flush(void)
sio_flush.0: call sio_getc.1 # Get character
sio_flush: call sio_ischar # Check for character
jnz sio_flush.0 # Till none
ret # To caller
# void sio_putc(int c)
sio_putc: movw $SIO_PRT+0x5,%dx # Line status reg
xor %ecx,%ecx # Timeout
movb $0x40,%ch # counter
sio_putc.1: inb (%dx),%al # Transmitter
testb $0x20,%al # buffer empty?
loopz sio_putc.1 # No
jz sio_putc.2 # If timeout
movb 0x4(%esp,1),%al # Get character
subb $0x5,%dl # Transmitter hold reg
outb %al,(%dx) # Write character
sio_putc.2: ret $0x4 # To caller
# int sio_getc(void)
sio_getc: call sio_ischar # Character available?
jz sio_getc # No
sio_getc.1: subb $0x5,%dl # Receiver buffer reg
inb (%dx),%al # Read character
ret # To caller
# int sio_ischar(void)
sio_ischar: movw $SIO_PRT+0x5,%dx # Line status register
xorl %eax,%eax # Zero
inb (%dx),%al # Received data
andb $0x1,%al # ready?
ret # To caller
#
# Output character AL to the serial console.
#
putchr: pusha # Save
cmpb $10, %al # is it a newline?
jne putchr.1 # no?, then leave
push $13 # output a carriage
call sio_putc # return first
movb $10, %al # restore %al
putchr.1: pushl %eax # Push the character
# onto the stack
call sio_putc # Output the character
popa # Restore
ret # To caller
',`
#
# Output character AL to the console.
#

77
sys/boot/i386/btx/btx/btx.s
View File

@ -240,6 +240,9 @@ init.8: xorl %ecx,%ecx # Zero
movb $0x7,%cl # Set remaining
init.9: push $0x0 # general
loop init.9 # registers
ifdef(`BTX_SERIAL',`
call sio_init # setup the serial console
')
popa # and initialize
popl %es # Initialize
popl %ds # user
@ -967,6 +970,80 @@ putstr: lodsb # Load char
testb %al,%al # End of string?
jnz putstr.0 # No
ret # To caller
ifdef(`BTX_SERIAL',`
.set SIO_PRT,SIOPRT # Base port
.set SIO_FMT,SIOFMT # 8N1
.set SIO_DIV,(115200/SIOSPD) # 115200 / SPD
# void sio_init(void)
sio_init: movw $SIO_PRT+0x3,%dx # Data format reg
movb $SIO_FMT|0x80,%al # Set format
outb %al,(%dx) # and DLAB
pushl %edx # Save
subb $0x3,%dl # Divisor latch reg
movw $SIO_DIV,%ax # Set
outw %ax,(%dx) # BPS
popl %edx # Restore
movb $SIO_FMT,%al # Clear
outb %al,(%dx) # DLAB
incl %edx # Modem control reg
movb $0x3,%al # Set RTS,
outb %al,(%dx) # DTR
incl %edx # Line status reg
# void sio_flush(void)
sio_flush.0: call sio_getc.1 # Get character
sio_flush: call sio_ischar # Check for character
jnz sio_flush.0 # Till none
ret # To caller
# void sio_putc(int c)
sio_putc: movw $SIO_PRT+0x5,%dx # Line status reg
xor %ecx,%ecx # Timeout
movb $0x40,%ch # counter
sio_putc.1: inb (%dx),%al # Transmitter
testb $0x20,%al # buffer empty?
loopz sio_putc.1 # No
jz sio_putc.2 # If timeout
movb 0x4(%esp,1),%al # Get character
subb $0x5,%dl # Transmitter hold reg
outb %al,(%dx) # Write character
sio_putc.2: ret $0x4 # To caller
# int sio_getc(void)
sio_getc: call sio_ischar # Character available?
jz sio_getc # No
sio_getc.1: subb $0x5,%dl # Receiver buffer reg
inb (%dx),%al # Read character
ret # To caller
# int sio_ischar(void)
sio_ischar: movw $SIO_PRT+0x5,%dx # Line status register
xorl %eax,%eax # Zero
inb (%dx),%al # Received data
andb $0x1,%al # ready?
ret # To caller
#
# Output character AL to the serial console.
#
putchr: pusha # Save
cmpb $10, %al # is it a newline?
jne putchr.1 # no?, then leave
push $13 # output a carriage
call sio_putc # return first
movb $10, %al # restore %al
putchr.1: pushl %eax # Push the character
# onto the stack
call sio_putc # Output the character
popa # Restore
ret # To caller
',`
#
# Output character AL to the console.
#