Merge from projects/mips to head by hand:

Special linker file for octeon1 in pseudo-32-bit mode.

sys/conf/ldscript.mips.octeon1.32

@@ -0,0 +1,58 @@
+/*
+ *    This product includes software developed by the University of
+ *    California, Berkeley and its contributors."
+*/
+OUTPUT_FORMAT("elf32-tradbigmips", "elf32-tradbigmips", "elf32-tradlittlemips")
+OUTPUT_ARCH(mips)
+ENTRY(_start)
+
+SECTIONS {
+	. = KERNLOADADDR + SIZEOF_HEADERS;
+	.text . : {
+	    	*(.text)
+		*(.dynamic)
+		etext = .;
+		_etext = .;
+		. = ALIGN(0x2000);
+	}
+
+	.rodata ALIGN(0x2000) : {
+		_fdata = .;
+	    	*(.rodata)
+		. = ALIGN(32);
+	}
+	
+	.data . : {
+                _rwdata = .;
+	    	*(.data)
+		. = ALIGN(32);
+		CONSTRUCTORS;
+	}
+
+	_gp = (. + 0x8000);
+
+	.sdata . : {
+                _small_start = .;
+		*(.sdata)
+		. = ALIGN(32);
+		edata = .;
+		_edata = .;
+	}
+
+	.sbss . : {
+		__bss_start = .;
+		_fbss = .;
+		*(.sbss) *(.scommon)
+                _small_end = .;
+		. = ALIGN(32);
+	}
+
+	.bss . : {
+		*(.bss)
+		*(COMMON)
+		. = ALIGN(32);
+		_end = .;
+		end = .;
+	}
+
+}