93 lines
2.0 KiB
Awk
93 lines
2.0 KiB
Awk
# Generate a flat list of symbols to export.
|
|
# Contributed by Richard Henderson <rth@cygnus.com>
|
|
#
|
|
# This file is part of GCC.
|
|
#
|
|
# GCC is free software; you can redistribute it and/or modify it under
|
|
# the terms of the GNU General Public License as published by the Free
|
|
# Software Foundation; either version 2, or (at your option) any later
|
|
# version.
|
|
#
|
|
# GCC is distributed in the hope that it will be useful, but WITHOUT
|
|
# ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
|
|
# or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public
|
|
# License for more details.
|
|
#
|
|
# You should have received a copy of the GNU General Public License
|
|
# along with GCC; see the file COPYING. If not, write to the Free
|
|
# Software Foundation, 51 Franklin Street, Fifth Floor, Boston MA
|
|
# 02110-1301, USA.
|
|
|
|
BEGIN {
|
|
state = "nm";
|
|
excluding = 0;
|
|
if (leading_underscore)
|
|
prefix = "_";
|
|
else
|
|
prefix = "";
|
|
}
|
|
|
|
# Remove comment and blank lines.
|
|
/^ *#/ || /^ *$/ {
|
|
next;
|
|
}
|
|
|
|
# We begin with nm input. Collect the set of symbols that are present
|
|
# so that we can elide undefined symbols.
|
|
|
|
state == "nm" && /^%%/ {
|
|
state = "ver";
|
|
next;
|
|
}
|
|
|
|
state == "nm" && ($1 == "U" || $2 == "U") {
|
|
next;
|
|
}
|
|
|
|
state == "nm" && NF == 3 {
|
|
def[$3] = 1;
|
|
next;
|
|
}
|
|
|
|
state == "nm" {
|
|
next;
|
|
}
|
|
|
|
# Now we process a simplified variant of the Solaris symbol version
|
|
# script. We have one symbol per line, no semicolons, simple markers
|
|
# for beginning and ending each section, and %inherit markers for
|
|
# describing version inheritence. A symbol may appear in more than
|
|
# one symbol version, and the last seen takes effect.
|
|
# The magic version name '%exclude' causes all the symbols given that
|
|
# version to be dropped from the output (unless a later version overrides).
|
|
|
|
NF == 3 && $1 == "%inherit" {
|
|
next;
|
|
}
|
|
|
|
NF == 2 && $2 == "{" {
|
|
if ($1 == "%exclude")
|
|
excluding = 1;
|
|
next;
|
|
}
|
|
|
|
$1 == "}" {
|
|
excluding = 0;
|
|
next;
|
|
}
|
|
|
|
{
|
|
sym = prefix $1;
|
|
if (excluding)
|
|
delete export[sym];
|
|
else
|
|
export[sym] = 1;
|
|
next;
|
|
}
|
|
|
|
END {
|
|
for (sym in export)
|
|
if (def[sym])
|
|
print sym;
|
|
}
|