c38367c73f
PaX/GrSecurity patched kernels implement a dialect of C that relies on a GCC plugin for enforcement. A basic idea in this dialect is that function pointers in structures should not change during runtime. This causes code that modifies function pointers at runtime to fail to compile in many instances. The autotools checks rely on whether or not small test cases compile against a given kernel. Some autotools checks assume some default case if other cases fail. When one of these autotools checks tests a PaX/GrSecurity patched kernel by modifying a function pointer at runtime, the default case will be used. Early detection of such situations is possible by relying on compiler warnings, which are compiler errors when --enable-debug is used. Unfortunately, very few people build ZFS with --enable-debug. The more common situation is that these issues manifest themselves as runtime failures in the form of NULL pointer exceptions. Previous patches that addressed such issues with PaX/GrSecurity compatibility largely relied on rewriting autotools checks to avoid runtime function pointer modification or the addition of PaX/GrSecurity specific checks. This patch takes the previous work to its logical conclusion by eliminating the use of runtime function pointer modification. This permits the removal of PaX-specific autotools checks in favor of ones that work across all supported kernels. This should resolve issues that were reported to occur with PaX/GrSecurity-patched Linux 3.7.5 kernels on Gentoo Linux. https://bugs.gentoo.org/show_bug.cgi?id=457176 We should be able to prevent future regressions in PaX/GrSecurity compatibility by ensuring that all changes to ZFSOnLinux avoid runtime function pointer modification. At the same time, this does not solve the issue of silent failures triggering default cases in the autotools check, which is what permitted these regressions to become runtime failures in the first place. This will need to be addressed in a future patch. Reported-by: Marcin Mirosław <bug@mejor.pl> Signed-off-by: Richard Yao <ryao@cs.stonybrook.edu> Signed-off-by: Brian Behlendorf <behlendorf1@llnl.gov> Closes #1300
75 lines
1.5 KiB
Plaintext
75 lines
1.5 KiB
Plaintext
dnl #
|
|
dnl # Linux 2.6.x - 2.6.34 API
|
|
dnl #
|
|
AC_DEFUN([ZFS_AC_KERNEL_FSYNC_WITH_DENTRY], [
|
|
ZFS_LINUX_TRY_COMPILE([
|
|
#include <linux/fs.h>
|
|
|
|
int test_fsync(struct file *f, struct dentry *dentry, int x)
|
|
{ return 0; }
|
|
|
|
static const struct file_operations
|
|
fops __attribute__ ((unused)) = {
|
|
.fsync = test_fsync,
|
|
};
|
|
],[
|
|
],[
|
|
AC_MSG_RESULT([dentry])
|
|
AC_DEFINE(HAVE_FSYNC_WITH_DENTRY, 1,
|
|
[fops->fsync() with dentry])
|
|
],[
|
|
])
|
|
])
|
|
|
|
dnl #
|
|
dnl # Linux 2.6.35 - Linux 3.0 API
|
|
dnl #
|
|
AC_DEFUN([ZFS_AC_KERNEL_FSYNC_WITHOUT_DENTRY], [
|
|
ZFS_LINUX_TRY_COMPILE([
|
|
#include <linux/fs.h>
|
|
|
|
int test_fsync(struct file *f, int x) { return 0; }
|
|
|
|
static const struct file_operations
|
|
fops __attribute__ ((unused)) = {
|
|
.fsync = test_fsync,
|
|
};
|
|
],[
|
|
],[
|
|
AC_MSG_RESULT([no dentry])
|
|
AC_DEFINE(HAVE_FSYNC_WITHOUT_DENTRY, 1,
|
|
[fops->fsync() without dentry])
|
|
],[
|
|
])
|
|
])
|
|
|
|
dnl #
|
|
dnl # Linux 3.1 - 3.x API
|
|
dnl #
|
|
AC_DEFUN([ZFS_AC_KERNEL_FSYNC_RANGE], [
|
|
ZFS_LINUX_TRY_COMPILE([
|
|
#include <linux/fs.h>
|
|
|
|
int test_fsync(struct file *f, loff_t a, loff_t b, int c)
|
|
{ return 0; }
|
|
|
|
static const struct file_operations
|
|
fops __attribute__ ((unused)) = {
|
|
.fsync = test_fsync,
|
|
};
|
|
],[
|
|
],[
|
|
AC_MSG_RESULT([range])
|
|
AC_DEFINE(HAVE_FSYNC_RANGE, 1,
|
|
[fops->fsync() with range])
|
|
],[
|
|
])
|
|
])
|
|
|
|
AC_DEFUN([ZFS_AC_KERNEL_FSYNC], [
|
|
AC_MSG_CHECKING([whether fops->fsync() wants])
|
|
ZFS_AC_KERNEL_FSYNC_WITH_DENTRY
|
|
ZFS_AC_KERNEL_FSYNC_WITHOUT_DENTRY
|
|
ZFS_AC_KERNEL_FSYNC_RANGE
|
|
])
|