adcd70bd1a
The Linux 3.1 kernel updated the fops->fsync() callback yet again. They now pass the requested range and delegate the responsibility for calling filemap_write_and_wait_range() to the callback. In addition imutex is no longer held by the caller and the callback is responsible for taking the lock if required. This commit updates the code to provide a zpl_fsync() function for the updated API. Implementations for the previous two APIs are also maintained for compatibility. Signed-off-by: Brian Behlendorf <behlendorf1@llnl.gov> Closes #445
64 lines
1.3 KiB
Plaintext
64 lines
1.3 KiB
Plaintext
dnl #
|
|
dnl # Linux 2.6.x - 2.6.34 API
|
|
dnl #
|
|
AC_DEFUN([ZFS_AC_KERNEL_FSYNC_WITH_DENTRY], [
|
|
ZFS_LINUX_TRY_COMPILE([
|
|
#include <linux/fs.h>
|
|
],[
|
|
int (*fsync) (struct file *, struct dentry *, int) = NULL;
|
|
struct file_operations fops __attribute__ ((unused));
|
|
|
|
fops.fsync = fsync;
|
|
],[
|
|
AC_MSG_RESULT([dentry])
|
|
AC_DEFINE(HAVE_FSYNC_WITH_DENTRY, 1,
|
|
[fops->fsync() with dentry])
|
|
],[
|
|
])
|
|
])
|
|
|
|
dnl #
|
|
dnl # Linux 2.6.35 - Linux 3.0 API
|
|
dnl #
|
|
AC_DEFUN([ZFS_AC_KERNEL_FSYNC_WITHOUT_DENTRY], [
|
|
ZFS_LINUX_TRY_COMPILE([
|
|
#include <linux/fs.h>
|
|
],[
|
|
int (*fsync) (struct file *, int) = NULL;
|
|
struct file_operations fops __attribute__ ((unused));
|
|
|
|
fops.fsync = fsync;
|
|
],[
|
|
AC_MSG_RESULT([no dentry])
|
|
AC_DEFINE(HAVE_FSYNC_WITHOUT_DENTRY, 1,
|
|
[fops->fsync() without dentry])
|
|
],[
|
|
])
|
|
])
|
|
|
|
dnl #
|
|
dnl # Linux 3.1 -x 3.x API
|
|
dnl #
|
|
AC_DEFUN([ZFS_AC_KERNEL_FSYNC_RANGE], [
|
|
ZFS_LINUX_TRY_COMPILE([
|
|
#include <linux/fs.h>
|
|
],[
|
|
int (*fsync) (struct file *, loff_t, loff_t, int) = NULL;
|
|
struct file_operations fops __attribute__ ((unused));
|
|
|
|
fops.fsync = fsync;
|
|
],[
|
|
AC_MSG_RESULT([range])
|
|
AC_DEFINE(HAVE_FSYNC_RANGE, 1,
|
|
[fops->fsync() with range])
|
|
],[
|
|
])
|
|
])
|
|
|
|
AC_DEFUN([ZFS_AC_KERNEL_FSYNC], [
|
|
AC_MSG_CHECKING([whether fops->fsync() wants])
|
|
ZFS_AC_KERNEL_FSYNC_WITH_DENTRY
|
|
ZFS_AC_KERNEL_FSYNC_WITHOUT_DENTRY
|
|
ZFS_AC_KERNEL_FSYNC_RANGE
|
|
])
|