608f8749a1
Reduce the time required for ./configure to perform the needed
KABI checks by allowing kbuild to compile multiple test cases in
parallel. This was accomplished by splitting each test's source
code from the logic handling whether that code could be compiled
or not.
By introducing this split it's possible to minimize the number of
times kbuild needs to be invoked. As importantly, it means all of
the tests can be built in parallel. This does require a little extra
care since we expect some tests to fail, so the --keep-going (-k)
option must be provided otherwise some tests may not get compiled.
Furthermore, since a failure during the kbuild modpost phase will
result in an early exit; the final linking phase is limited to tests
which passed the initial compilation and produced an object file.
Once everything has been built the configure script proceeds as
previously. The only significant difference is that it now merely
needs to test for the existence of a .ko file to determine the
result of a given test. This vastly speeds up the entire process.
New test cases should use ZFS_LINUX_TEST_SRC to declare their test
source code and ZFS_LINUX_TEST_RESULT to check the result. All of
the existing kernel-*.m4 files have been updated accordingly, see
config/kernel-current-time.m4 for a basic example. The legacy
ZFS_LINUX_TRY_COMPILE macro has been kept to handle special cases
but it's use is not encouraged.
master (secs) patched (secs)
------------- ----------------
autogen.sh 61 68
configure 137 24 (~17% of current run time)
make -j $(nproc) 44 44
make rpms 287 150
Reviewed-by: Tony Hutter <hutter2@llnl.gov>
Signed-off-by: Brian Behlendorf <behlendorf1@llnl.gov>
Closes #8547
Closes #9132
Closes #9341
74 lines
2.5 KiB
Plaintext
74 lines
2.5 KiB
Plaintext
dnl #
|
|
dnl # 2.6.39 API change
|
|
dnl # The security_inode_init_security() function now takes an additional
|
|
dnl # qstr argument which must be passed in from the dentry if available.
|
|
dnl # Passing a NULL is safe when no qstr is available the relevant
|
|
dnl # security checks will just be skipped.
|
|
dnl #
|
|
AC_DEFUN([ZFS_AC_KERNEL_SRC_SECURITY_INODE_INIT_SECURITY_6ARGS], [
|
|
ZFS_LINUX_TEST_SRC([security_inode_init_security_6args], [
|
|
#include <linux/security.h>
|
|
],[
|
|
struct inode *ip __attribute__ ((unused)) = NULL;
|
|
struct inode *dip __attribute__ ((unused)) = NULL;
|
|
const struct qstr *str __attribute__ ((unused)) = NULL;
|
|
char *name __attribute__ ((unused)) = NULL;
|
|
void *value __attribute__ ((unused)) = NULL;
|
|
size_t len __attribute__ ((unused)) = 0;
|
|
|
|
security_inode_init_security(ip, dip, str, &name, &value, &len);
|
|
])
|
|
])
|
|
|
|
AC_DEFUN([ZFS_AC_KERNEL_SECURITY_INODE_INIT_SECURITY_6ARGS], [
|
|
AC_MSG_CHECKING([whether security_inode_init_security wants 6 args])
|
|
ZFS_LINUX_TEST_RESULT([security_inode_init_security_6args], [
|
|
AC_MSG_RESULT(yes)
|
|
AC_DEFINE(HAVE_6ARGS_SECURITY_INODE_INIT_SECURITY, 1,
|
|
[security_inode_init_security wants 6 args])
|
|
],[
|
|
AC_MSG_RESULT(no)
|
|
])
|
|
])
|
|
|
|
dnl #
|
|
dnl # 3.2 API change
|
|
dnl # The security_inode_init_security() API has been changed to include
|
|
dnl # a filesystem specific callback to write security extended attributes.
|
|
dnl # This was done to support the initialization of multiple LSM xattrs
|
|
dnl # and the EVM xattr.
|
|
dnl #
|
|
AC_DEFUN([ZFS_AC_KERNEL_SRC_SECURITY_INODE_INIT_SECURITY_CALLBACK], [
|
|
ZFS_LINUX_TEST_SRC([security_inode_init_security], [
|
|
#include <linux/security.h>
|
|
],[
|
|
struct inode *ip __attribute__ ((unused)) = NULL;
|
|
struct inode *dip __attribute__ ((unused)) = NULL;
|
|
const struct qstr *str __attribute__ ((unused)) = NULL;
|
|
initxattrs func __attribute__ ((unused)) = NULL;
|
|
|
|
security_inode_init_security(ip, dip, str, func, NULL);
|
|
])
|
|
])
|
|
|
|
AC_DEFUN([ZFS_AC_KERNEL_SECURITY_INODE_INIT_SECURITY_CALLBACK], [
|
|
AC_MSG_CHECKING([whether security_inode_init_security wants callback])
|
|
ZFS_LINUX_TEST_RESULT([security_inode_init_security], [
|
|
AC_MSG_RESULT(yes)
|
|
AC_DEFINE(HAVE_CALLBACK_SECURITY_INODE_INIT_SECURITY, 1,
|
|
[security_inode_init_security wants callback])
|
|
],[
|
|
AC_MSG_RESULT(no)
|
|
])
|
|
])
|
|
|
|
AC_DEFUN([ZFS_AC_KERNEL_SRC_SECURITY_INODE], [
|
|
ZFS_AC_KERNEL_SRC_SECURITY_INODE_INIT_SECURITY_6ARGS
|
|
ZFS_AC_KERNEL_SRC_SECURITY_INODE_INIT_SECURITY_CALLBACK
|
|
])
|
|
|
|
AC_DEFUN([ZFS_AC_KERNEL_SECURITY_INODE], [
|
|
ZFS_AC_KERNEL_SECURITY_INODE_INIT_SECURITY_6ARGS
|
|
ZFS_AC_KERNEL_SECURITY_INODE_INIT_SECURITY_CALLBACK
|
|
])
|