608f8749a1
Reduce the time required for ./configure to perform the needed
KABI checks by allowing kbuild to compile multiple test cases in
parallel. This was accomplished by splitting each test's source
code from the logic handling whether that code could be compiled
or not.
By introducing this split it's possible to minimize the number of
times kbuild needs to be invoked. As importantly, it means all of
the tests can be built in parallel. This does require a little extra
care since we expect some tests to fail, so the --keep-going (-k)
option must be provided otherwise some tests may not get compiled.
Furthermore, since a failure during the kbuild modpost phase will
result in an early exit; the final linking phase is limited to tests
which passed the initial compilation and produced an object file.
Once everything has been built the configure script proceeds as
previously. The only significant difference is that it now merely
needs to test for the existence of a .ko file to determine the
result of a given test. This vastly speeds up the entire process.
New test cases should use ZFS_LINUX_TEST_SRC to declare their test
source code and ZFS_LINUX_TEST_RESULT to check the result. All of
the existing kernel-*.m4 files have been updated accordingly, see
config/kernel-current-time.m4 for a basic example. The legacy
ZFS_LINUX_TRY_COMPILE macro has been kept to handle special cases
but it's use is not encouraged.
master (secs) patched (secs)
------------- ----------------
autogen.sh 61 68
configure 137 24 (~17% of current run time)
make -j $(nproc) 44 44
make rpms 287 150
Reviewed-by: Tony Hutter <hutter2@llnl.gov>
Signed-off-by: Brian Behlendorf <behlendorf1@llnl.gov>
Closes #8547
Closes #9132
Closes #9341
84 lines
2.2 KiB
Plaintext
84 lines
2.2 KiB
Plaintext
AC_DEFUN([ZFS_AC_KERNEL_SRC_VFS_ITERATE], [
|
|
ZFS_LINUX_TEST_SRC([file_operations_iterate_shared], [
|
|
#include <linux/fs.h>
|
|
int iterate(struct file *filp, struct dir_context * context)
|
|
{ return 0; }
|
|
|
|
static const struct file_operations fops
|
|
__attribute__ ((unused)) = {
|
|
.iterate_shared = iterate,
|
|
};
|
|
],[])
|
|
|
|
ZFS_LINUX_TEST_SRC([file_operations_iterate], [
|
|
#include <linux/fs.h>
|
|
int iterate(struct file *filp,
|
|
struct dir_context *context) { return 0; }
|
|
|
|
static const struct file_operations fops
|
|
__attribute__ ((unused)) = {
|
|
.iterate = iterate,
|
|
};
|
|
|
|
#if defined(FMODE_KABI_ITERATE)
|
|
#error "RHEL 7.5, FMODE_KABI_ITERATE interface"
|
|
#endif
|
|
],[])
|
|
|
|
ZFS_LINUX_TEST_SRC([file_operations_readdir], [
|
|
#include <linux/fs.h>
|
|
int readdir(struct file *filp, void *entry,
|
|
filldir_t func) { return 0; }
|
|
|
|
static const struct file_operations fops
|
|
__attribute__ ((unused)) = {
|
|
.readdir = readdir,
|
|
};
|
|
],[])
|
|
])
|
|
|
|
AC_DEFUN([ZFS_AC_KERNEL_VFS_ITERATE], [
|
|
dnl #
|
|
dnl # 4.7 API change
|
|
dnl #
|
|
AC_MSG_CHECKING([whether fops->iterate_shared() is available])
|
|
ZFS_LINUX_TEST_RESULT([file_operations_iterate_shared], [
|
|
AC_MSG_RESULT(yes)
|
|
AC_DEFINE(HAVE_VFS_ITERATE_SHARED, 1,
|
|
[fops->iterate_shared() is available])
|
|
],[
|
|
AC_MSG_RESULT(no)
|
|
|
|
dnl #
|
|
dnl # 3.11 API change
|
|
dnl #
|
|
dnl # RHEL 7.5 compatibility; the fops.iterate() method was
|
|
dnl # added to the file_operations structure but in order to
|
|
dnl # maintain KABI compatibility all callers must set
|
|
dnl # FMODE_KABI_ITERATE which is checked in iterate_dir().
|
|
dnl # When detected ignore this interface and fallback to
|
|
dnl # to using fops.readdir() to retain KABI compatibility.
|
|
dnl #
|
|
AC_MSG_CHECKING([whether fops->iterate() is available])
|
|
ZFS_LINUX_TEST_RESULT([file_operations_iterate], [
|
|
AC_MSG_RESULT(yes)
|
|
AC_DEFINE(HAVE_VFS_ITERATE, 1,
|
|
[fops->iterate() is available])
|
|
],[
|
|
AC_MSG_RESULT(no)
|
|
|
|
dnl #
|
|
dnl # readdir interface introduced
|
|
dnl #
|
|
AC_MSG_CHECKING([whether fops->readdir() is available])
|
|
ZFS_LINUX_TEST_RESULT([file_operations_readdir], [
|
|
AC_MSG_RESULT(yes)
|
|
AC_DEFINE(HAVE_VFS_READDIR, 1,
|
|
[fops->readdir() is available])
|
|
],[
|
|
ZFS_LINUX_TEST_ERROR([vfs_iterate])
|
|
])
|
|
])
|
|
])
|
|
])
|