90 lines
2.7 KiB
ArmAsm
90 lines
2.7 KiB
ArmAsm
/*
|
|
* Copyright (c) 1993 Winning Strategies, Inc.
|
|
* All rights reserved.
|
|
*
|
|
* Redistribution and use in source and binary forms, with or without
|
|
* modification, are permitted provided that the following conditions
|
|
* are met:
|
|
* 1. Redistributions of source code must retain the above copyright
|
|
* notice, this list of conditions and the following disclaimer.
|
|
* 2. Redistributions in binary form must reproduce the above copyright
|
|
* notice, this list of conditions and the following disclaimer in the
|
|
* documentation and/or other materials provided with the distribution.
|
|
* 3. All advertising materials mentioning features or use of this software
|
|
* must display the following acknowledgement:
|
|
* This product includes software developed by Winning Strategies, Inc.
|
|
* 4. The name of the author may not be used to endorse or promote products
|
|
* derived from this software without specific prior written permission
|
|
*
|
|
* THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
|
|
* IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
|
|
* OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
|
|
* IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
|
|
* INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
|
|
* NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
|
|
* DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
|
|
* THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
|
|
* (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
|
|
* THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
|
|
*/
|
|
|
|
#include <machine/asm.h>
|
|
__FBSDID("$FreeBSD$");
|
|
|
|
/*
|
|
* memset(void *b, int c, size_t len)
|
|
* write len bytes of value c (converted to an unsigned char) to
|
|
* the string b.
|
|
*
|
|
* Written by:
|
|
* J.T. Conklin (jtc@wimsey.com), Winning Strategies, Inc.
|
|
*/
|
|
|
|
ENTRY(memset)
|
|
pushl %edi
|
|
pushl %ebx
|
|
movl 12(%esp),%edi
|
|
movzbl 16(%esp),%eax /* unsigned char, zero extend */
|
|
movl 20(%esp),%ecx
|
|
pushl %edi /* push address of buffer */
|
|
|
|
cld /* set fill direction forward */
|
|
|
|
/*
|
|
* if the string is too short, it's really not worth the overhead
|
|
* of aligning to word boundries, etc. So we jump to a plain
|
|
* unaligned set.
|
|
*/
|
|
cmpl $0x0f,%ecx
|
|
jle L1
|
|
|
|
movb %al,%ah /* copy char to all bytes in word */
|
|
movl %eax,%edx
|
|
sall $16,%eax
|
|
orl %edx,%eax
|
|
|
|
movl %edi,%edx /* compute misalignment */
|
|
negl %edx
|
|
andl $3,%edx
|
|
movl %ecx,%ebx
|
|
subl %edx,%ebx
|
|
|
|
movl %edx,%ecx /* set until word aligned */
|
|
rep
|
|
stosb
|
|
|
|
movl %ebx,%ecx
|
|
shrl $2,%ecx /* set by words */
|
|
rep
|
|
stosl
|
|
|
|
movl %ebx,%ecx /* set remainder by bytes */
|
|
andl $3,%ecx
|
|
L1: rep
|
|
stosb
|
|
|
|
popl %eax /* pop address of buffer */
|
|
popl %ebx
|
|
popl %edi
|
|
ret
|