205 lines
7.9 KiB
C
205 lines
7.9 KiB
C
|
/* $NetBSD: frame.h,v 1.6 2003/10/05 19:44:58 matt Exp $ */
|
||
|
|
|
||
|
|
/*
|
||
|
|
* Copyright (c) 1994-1997 Mark Brinicombe.
|
||
|
|
* Copyright (c) 1994 Brini.
|
||
|
|
* All rights reserved.
|
||
|
|
*
|
||
|
|
* This code is derived from software written for Brini by Mark Brinicombe
|
||
|
|
*
|
||
|
|
* Redistribution and use in source and binary forms, with or without
|
||
|
|
* modification, are permitted provided that the following conditions
|
||
|
|
* are met:
|
||
|
|
* 1. Redistributions of source code must retain the above copyright
|
||
|
|
* notice, this list of conditions and the following disclaimer.
|
||
|
|
* 2. Redistributions in binary form must reproduce the above copyright
|
||
|
|
* notice, this list of conditions and the following disclaimer in the
|
||
|
|
* documentation and/or other materials provided with the distribution.
|
||
|
|
* 3. All advertising materials mentioning features or use of this software
|
||
|
|
* must display the following acknowledgement:
|
||
|
|
* This product includes software developed by Brini.
|
||
|
|
* 4. The name of the company nor the name of the author may be used to
|
||
|
|
* endorse or promote products derived from this software without specific
|
||
|
|
* prior written permission.
|
||
|
|
*
|
||
|
|
* THIS SOFTWARE IS PROVIDED BY BRINI ``AS IS'' AND ANY EXPRESS OR IMPLIED
|
||
|
|
* WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
|
||
|
|
* MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
|
||
|
|
* IN NO EVENT SHALL BRINI OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT,
|
||
|
|
* INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
|
||
|
|
* (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
|
||
|
|
* SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
|
||
|
|
* HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
|
||
|
|
* LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
|
||
|
|
* OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
|
||
|
|
* SUCH DAMAGE.
|
||
|
|
*
|
||
|
|
* $FreeBSD$
|
||
|
|
*/
|
||
|
|
|
||
|
|
#ifndef _MACHINE_ASMACROS_H_
|
||
|
|
#define _MACHINE_ASMACROS_H_
|
||
|
|
|
||
|
|
#ifdef _KERNEL
|
||
|
|
|
||
|
|
#ifdef LOCORE
|
||
|
|
|
||
|
|
/*
|
||
|
|
* ASM macros for pushing and pulling trapframes from the stack
|
||
|
|
*
|
||
|
|
* These macros are used to handle the irqframe and trapframe structures
|
||
|
|
* defined above.
|
||
|
|
*/
|
||
|
|
|
||
|
|
/*
|
||
|
|
* PUSHFRAME - macro to push a trap frame on the stack in the current mode
|
||
|
|
* Since the current mode is used, the SVC lr field is not defined.
|
||
|
|
*
|
||
|
|
* NOTE: r13 and r14 are stored separately as a work around for the
|
||
|
|
* SA110 rev 2 STM^ bug
|
||
|
|
*/
|
||
|
|
|
||
|
|
#define PUSHFRAME \
|
||
|
|
str lr, [sp, #-4]!; /* Push the return address */ \
|
||
|
|
sub sp, sp, #(4*17); /* Adjust the stack pointer */ \
|
||
|
|
stmia sp, {r0-r12}; /* Push the user mode registers */ \
|
||
|
|
add r0, sp, #(4*13); /* Adjust the stack pointer */ \
|
||
|
|
stmia r0, {r13-r14}^; /* Push the user mode registers */ \
|
||
|
|
mov r0, r0; /* NOP for previous instruction */ \
|
||
|
|
mrs r0, spsr_all; /* Put the SPSR on the stack */ \
|
||
|
|
str r0, [sp, #-4]!;
|
||
|
|
|
||
|
|
/*
|
||
|
|
* PULLFRAME - macro to pull a trap frame from the stack in the current mode
|
||
|
|
* Since the current mode is used, the SVC lr field is ignored.
|
||
|
|
*/
|
||
|
|
|
||
|
|
#define PULLFRAME \
|
||
|
|
ldr r0, [sp], #0x0004; /* Get the SPSR from stack */ \
|
||
|
|
msr spsr_all, r0; \
|
||
|
|
ldmia sp, {r0-r14}^; /* Restore registers (usr mode) */ \
|
||
|
|
mov r0, r0; /* NOP for previous instruction */ \
|
||
|
|
add sp, sp, #(4*17); /* Adjust the stack pointer */ \
|
||
|
|
ldr lr, [sp], #0x0004; /* Pull the return address */
|
||
|
|
|
||
|
|
/*
|
||
|
|
* PUSHFRAMEINSVC - macro to push a trap frame on the stack in SVC32 mode
|
||
|
|
* This should only be used if the processor is not currently in SVC32
|
||
|
|
* mode. The processor mode is switched to SVC mode and the trap frame is
|
||
|
|
* stored. The SVC lr field is used to store the previous value of
|
||
|
|
* lr in SVC mode.
|
||
|
|
*
|
||
|
|
* NOTE: r13 and r14 are stored separately as a work around for the
|
||
|
|
* SA110 rev 2 STM^ bug
|
||
|
|
*/
|
||
|
|
|
||
|
|
#define PUSHFRAMEINSVC \
|
||
|
|
stmdb sp, {r0-r3}; /* Save 4 registers */ \
|
||
|
|
mov r0, lr; /* Save xxx32 r14 */ \
|
||
|
|
mov r1, sp; /* Save xxx32 sp */ \
|
||
|
|
mrs r3, spsr; /* Save xxx32 spsr */ \
|
||
|
|
mrs r2, cpsr; /* Get the CPSR */ \
|
||
|
|
bic r2, r2, #(PSR_MODE); /* Fix for SVC mode */ \
|
||
|
|
orr r2, r2, #(PSR_SVC32_MODE); \
|
||
|
|
msr cpsr_c, r2; /* Punch into SVC mode */ \
|
||
|
|
mov r2, sp; /* Save SVC sp */ \
|
||
|
|
str r0, [sp, #-4]!; /* Push return address */ \
|
||
|
|
str lr, [sp, #-4]!; /* Push SVC lr */ \
|
||
|
|
str r2, [sp, #-4]!; /* Push SVC sp */ \
|
||
|
|
msr spsr_all, r3; /* Restore correct spsr */ \
|
||
|
|
ldmdb r1, {r0-r3}; /* Restore 4 regs from xxx mode */ \
|
||
|
|
sub sp, sp, #(4*15); /* Adjust the stack pointer */ \
|
||
|
|
stmia sp, {r0-r12}; /* Push the user mode registers */ \
|
||
|
|
add r0, sp, #(4*13); /* Adjust the stack pointer */ \
|
||
|
|
stmia r0, {r13-r14}^; /* Push the user mode registers */ \
|
||
|
|
mov r0, r0; /* NOP for previous instruction */ \
|
||
|
|
mrs r0, spsr_all; /* Put the SPSR on the stack */ \
|
||
|
|
str r0, [sp, #-4]!
|
||
|
|
|
||
|
|
/*
|
||
|
|
* PULLFRAMEFROMSVCANDEXIT - macro to pull a trap frame from the stack
|
||
|
|
* in SVC32 mode and restore the saved processor mode and PC.
|
||
|
|
* This should be used when the SVC lr register needs to be restored on
|
||
|
|
* exit.
|
||
|
|
*/
|
||
|
|
|
||
|
|
#define PULLFRAMEFROMSVCANDEXIT \
|
||
|
|
ldr r0, [sp], #0x0004; /* Get the SPSR from stack */ \
|
||
|
|
msr spsr_all, r0; /* restore SPSR */ \
|
||
|
|
ldmia sp, {r0-r14}^; /* Restore registers (usr mode) */ \
|
||
|
|
mov r0, r0; /* NOP for previous instruction */ \
|
||
|
|
add sp, sp, #(4*15); /* Adjust the stack pointer */ \
|
||
|
|
ldmia sp, {sp, lr, pc}^ /* Restore lr and exit */
|
||
|
|
|
||
|
|
#define DATA(name) \
|
||
|
|
.data ; \
|
||
|
|
_ALIGN_DATA ; \
|
||
|
|
.globl name ; \
|
||
|
|
.type name, %object ; \
|
||
|
|
name:
|
||
|
|
|
||
|
|
#define EMPTY
|
||
|
|
|
||
|
|
|
||
|
|
#define GET_CURPCB_ENTER \
|
||
|
|
ldr r1, .Laflt_curpcb ;\
|
||
|
|
ldr r1, [r1]
|
||
|
|
|
||
|
|
/*
|
||
|
|
* This macro must be invoked following PUSHFRAMEINSVC or PUSHFRAME at
|
||
|
|
* the top of interrupt/exception handlers.
|
||
|
|
*
|
||
|
|
* When invoked, r0 *must* contain the value of SPSR on the current
|
||
|
|
* trap/interrupt frame. This is always the case if ENABLE_ALIGNMENT_FAULTS
|
||
|
|
* is invoked immediately after PUSHFRAMEINSVC or PUSHFRAME.
|
||
|
|
*/
|
||
|
|
#define ENABLE_ALIGNMENT_FAULTS \
|
||
|
|
and r0, r0, #(PSR_MODE) /* Test for USR32 mode */ ;\
|
||
|
|
teq r0, #(PSR_USR32_MODE) ;\
|
||
|
|
bne 1f /* Not USR mode skip AFLT */ ;\
|
||
|
|
GET_CURPCB_ENTER /* r1 = curpcb */ ;\
|
||
|
|
cmp r1, #0x00 /* curpcb NULL? */ ;\
|
||
|
|
ldrne r1, [r1, #PCB_FLAGS] /* Fetch curpcb->pcb_flags */ ;\
|
||
|
|
tstne r1, #PCB_NOALIGNFLT ;\
|
||
|
|
beq 1f /* AFLTs already enabled */ ;\
|
||
|
|
ldr r2, .Laflt_cpufuncs ;\
|
||
|
|
mov lr, pc ;\
|
||
|
|
ldr pc, [r2, #CF_CONTROL] /* Enable alignment faults */ ;\
|
||
|
|
1:
|
||
|
|
|
||
|
|
#define DO_AST_AND_RESTORE_ALIGNMENT_FAULTS \
|
||
|
|
ldr r0, [sp] /* Get the SPSR from stack */ ;\
|
||
|
|
mrs r4, cpsr /* save CPSR */ ;\
|
||
|
|
and r0, r0, #(PSR_MODE) /* Returning to USR mode? */ ;\
|
||
|
|
teq r0, #(PSR_USR32_MODE) ;\
|
||
|
|
bne 2f /* Nope, get out now */ ;\
|
||
|
|
bic r4, r4, #(I32_bit) ;\
|
||
|
|
1: orr r0, r4, #(I32_bit) /* Disable IRQs */ ;\
|
||
|
|
msr cpsr_c, r0 ;\
|
||
|
|
ldr r5, .Laflt_curthread ;\
|
||
|
|
ldr r5, [r5] ;\
|
||
|
|
ldr r5, [r5, #(TD_FLAGS)] ;\
|
||
|
|
and r5, r5, #(TDF_ASTPENDING) ;\
|
||
|
|
teq r5, #0x00000000 ;\
|
||
|
|
beq 2f /* Nope. Just bail */ ;\
|
||
|
|
msr cpsr_c, r4 /* Restore interrupts */ ;\
|
||
|
|
mov r0, sp ;\
|
||
|
|
adr lr, 1b ;\
|
||
|
|
b _C_LABEL(ast) /* ast(frame) */ ;\
|
||
|
|
2:
|
||
|
|
|
||
|
|
#define AST_ALIGNMENT_FAULT_LOCALS ;\
|
||
|
|
.Laflt_curpcb: ;\
|
||
|
|
.word _C_LABEL(__pcpu) + PC_CURPCB ;\
|
||
|
|
.Laflt_cpufuncs: ;\
|
||
|
|
.word _C_LABEL(cpufuncs) ;\
|
||
|
|
.Laflt_curthread: ;\
|
||
|
|
.word _C_LABEL(__pcpu) + PC_CURTHREAD
|
||
|
|
|
||
|
|
|
||
|
|
#endif /* LOCORE */
|
||
|
|
|
||
|
|
#endif /* _KERNEL */
|
||
|
|
|
||
|
|
#endif /* !_MACHINE_ASMACROS_H_ */
|